Mdthbs

I posted this question on Math, but there has been silence there since. So, I wonder if anyone here can get any closer to the answer to my question using Mathematica. Here is the question:

Suppose I draw $N$ random variables from independent but identical uniform distributions, where $N$ is an even integer. I now sort the drawn values and find the two middlemost of these. Finally, I calculate a simple average of these two middlemost values.

Is there a closed-form description of the progression of distributions that arise as $N$ increases from $N=2$ to $N=∞$ ? The first distribution is easily found to be Triangular, but what about the rest? Plots from simulations in MATLAB, with a uniform distribution on the range 0 to 1, provide the following illustrations:

A partial answer: here is a way to calculate these distributions exactly for any $n$ (given enough patience). Memoizing them with this trick.

f[n_Integer?Positive] := f[n] = Module[{v},

  (* make a list of n unique variables *)

  v = Table[Unique[], n];

  (* calculate the n-fold integral and return the distribution as a function *)

  Function[a, Evaluate@Assuming[0 < a < 1, 

    Integrate[DiracDelta[Mean[v] - a], 

      Sequence @@ ({#, 0, 1} & /@ v)] // FullSimplify]]]

update

You can calculate these much more easily with

f[n_Integer?Positive] := PDF[UniformSumDistribution[n, {0,1/n}]]

Test:

f[1][a]

(*    1    *)



f[2][a]

(*    2 (1 + (-1 + 2 a) HeavisideTheta[1 - 2 a] + (1 - 2 a) HeavisideTheta[-1 + 2 a])    *)

It looks like for given order $n$ the distribution is a combination of $n$ polynomials of order $n-1$, each taking up a fraction $1/n$ of the interval $[0,1]$. For example, for $n=3$ the distribution is composed of three parabolas (second-order polynomials), each spanning $1/3$ of the unit interval:

Assuming[0 < a < 1/3, f[3][a] // FullSimplify]

(*    (27 a^2)/2    *)

Assuming[1/3 < a < 2/3, f[3][a] // FullSimplify]

(*    -(9/2) (1 + 6 (-1 + a) a)    *)

Assuming[2/3 < a < 1, f[3][a] // FullSimplify]

(*    27/2 (-1 + a)^2    *)



Plot[Evaluate@Table[f[n][a], {n, 4}], {a, 0, 1}, PlotLegends -> Range[4]]

For $ntoinfty$ the distribution becomes Gaussian with mean $langle arangle=frac12$ and variance $langle a^2rangle-langle arangle^2=frac{1}{12n}$:

$$
p_{ngg1}(a) approx sqrt{frac{6n}{pi}} e^{-6n(a - 1/2)^2}
$$

Comparison for $n=4$:

With[{n = 4},

  Plot[{f[n][a], Sqrt[6n/π]*E^(-6n(a-1/2)^2)}, {a, 0, 1}, 

    PlotLegends -> {"exact", "Gaussian"}]]

Mathematica does make this pretty easy. The statistic of interest is the typical estimator of the median when the sample size is even. When the sample size is odd the sample median has a beta distribution:

OrderDistribution[{UniformDistribution[{0, 1}], n}, (n + 1)/2]

(* BetaDistribution[(1 + n)/2, 1 + 1/2 (-1 - n) + n] *)

Now for the case when $n$ is even. First find the joint distribution of the middle two order statistics. Then find the distribution of the mean of those two statistics.

n = 6;

od = OrderDistribution[{UniformDistribution[{0, 1}], n}, {n/2, n/2 + 1}];



md = TransformedDistribution[(x1 + x2)/2, {x1, x2} [Distributed] od];



PDF[md, x]

Plot[Evaluate[PDF[md, x]], {x, 0, 1}]

To obtain the distribution for general $n$ when $n$ is odd we have to use some other than TransformedDistribution. We need to integrate the joint density function and treat $0<x<1/2$, $x=1/2$, and $1/2<x<1$ separately.

fltOneHalf = 2 Integrate[(x1^(-1 + n/2) (1 - x2)^(-1 + n/2) n!)/((-1 + n/2)!)^2 /. 

  x2 -> 2 x - x1, {x1, 0, x}, Assumptions -> n > 1 && 0 < x < 1/2]

(* -((4 ((1 - 2 x) x)^(n/2) Gamma[n]*

  Hypergeometric2F1[1 - n/2, n/2, (2 + n)/2, x/(-1 + 2 x)])/((-1 + 2 x)*

  Gamma[n/2]^2)) *) 



fOneHalf = 2 Integrate[(x1^(-1 + n/2) (1 - x2)^(-1 + n/2) n!)/((-1 + n/2)!)^2 /.

  x2 -> 1 - x1, {x1, 0, 1/2}, Assumptions -> n > 1]

(* (2^(2 - n) n!)/((-1 + n) ((-1 + n/2)!)^2) *)



(* Because the density is symmetric, we'll take advantage of that *)

fgtOneHalf = FullSimplify[fltOneHalf /. x -> y /. y -> 1 - x]

(* (4 (-1 + (3 - 2 x) x)^(n/2) Gamma[n]*

  Hypergeometric2F1[1 - n/2, n/2, (2 + n)/2, (-1 + x)/(-1 + 2 x)])/((-1 + 2 x) Gamma[n/2]^2) *)

Putting this together in a single function:

pdf[n_, x_] := 

 Piecewise[{{-((4 ((1 - 2 x) x)^(n/2)*Gamma[n] Hypergeometric2F1[1 - n/2, n/2, (2 + n)/2, 

       x/(-1 + 2 x)])/((-1 + 2 x) Gamma[n/2]^2)), 0 < x < 1/2},

   {(2^(2 - n) n!)/((-1 + n) ((-1 + n/2)!)^2), x == 1/2},

   {(4 (-1 + (3 - 2 x) x)^(n/2) * Gamma[n]*

 Hypergeometric2F1[1 - n/2, n/2, (2 + n)/2, (-1 + x)/(-1 + 2 x)])/((-1 + 2 x) Gamma[n/2]^2), 

    1/2 < x < 1}}, 0]

Here's an interesting counter-example for a discrete uniform distribution does not tend to your shape as $N$ grows.

Let your r.v. $x$ be distributed as per a coin toss, taking value ${0,1}$ with equal probability. Then you have three possible outcomes after $N$ coin tosses; $0, 1/2$ , or $1$

The middle outcome's probability is the probability that with $N$ coin tosses you get exactly $N/2$ zeros or ones. This probability is

$$
2^{-n} binom{n}{frac{n}{2}}
$$

Which decreases in $N$, resulting in the plot below, with the distribution of probabilities of values with $N$

EDIT

You can see the same effect with the discrete distribution for $x$ expanded to take values $x={1, 2, ... , 50}$ with equal probability. The non-integer values are much less likely, since the odds of the two middle points hitting the boundary is low. The integers values do tend to a Guassian.

middleMean[n_, range_] := Module[{res}, 

     res = Sort@Table[RandomChoice[Range[range]], {n}];

     Mean[{res[[n/2]], res[[n/2 + 1]]}]

  ]



Histogram[Table[middleMean[500, 50], {1000}], 50]