Mdthbs

The following example prints the square and cube of numbers from 0.5 to 6

Do[

  Print[StringForm["the square of `` is ``, the cube of it is ``", i, i^2, i^3]], 

  {i, 0.5, 6, 0.1}]

It should be fine, however, for 0.7 Mathematica prints

the square of 0.7` is 0.48999999999999994`, the cube of it is 0.3429999999999999`

Why is the square of 0.7 approximated by 0.48999999999999994? No approximation will be made if I did not use StringForm, why is that?

By the way, there is a ` at the end of each output number, why is it there?

This is what happens when you use IEEE-754 double-precision math instead of exact math.

StringForm, InputForm, FullForm etc. give you all possible digits of these IEEE-754 double-precision numbers used internally. This is no different from any other programming language.

Other number display functions, like NumberForm, show fewer digits. The internal representation of the number doesn't change though.

The backtick ` indicates a machine-precision number, which is usually (always?) an IEEE-754 double-precision number.

You can get the result you're looking for by doing the conversion to numerical values after the squaring/cubing:

Do[Print[StringForm["the square of `` is ``, the cube of it is ``", 

  N[i], N[i^2], N[i^3]]], {i, 1/2, 6, 1/10}]

the square of 0.7` is 0.49`, the cube of it is 0.343`

StringForm is very old. It goes all the back to V1.0, released in 1988. It represents an attempt by WRI to have an IO formatter that would appeal to programmers familiar with C and similar programming languages.

V6.0, released in 2003, added formatting tools that are not only easier to use but which are better integrated into Mathematica's way of doing things. One of the new IO formatters was Row. It does not have the problem with formatting machine numbers that you ran into by using StringForm.

Here is how you can get your output with Row.

Column[

  Table[

    Row[{"the square of ", i, " is ", i^2, ", the cube of it is ", i^3}], 

    {i, 0.5, 1., .1}]]

One of the nice features of the newer IO formatting tools is that they allow styles to be applied at almost any level. For example:

numStyle[num_?NumericQ] := Style[num, Red, Bold, Italic]

Style[

  Column[

    Table[

      Row[

       {"the square of ", numStyle[i], " is ", numStyle[i^2], 

        ", the cube of it is ", numStyle[i^3]}],

    {i, 0.5, 1., .1}]],

  FontFamily -> "Arial"]

It isn't that you can't apply styles to StringForm output, but that it is harder to do and requires more care.

I would recommend looking at StringTemplate.

Do[Print[StringTemplate[

    "the square of `` is ``, the cube of it is ``"][i, i^2, i^3]], {i,

   0.5, 1, 0.1}]





the square of 0.5 is 0.25, the cube of it is 0.125



the square of 0.6 is 0.36, the cube of it is 0.216



the square of 0.7 is 0.49, the cube of it is 0.343



the square of 0.8 is 0.64, the cube of it is 0.512



the square of 0.9 is 0.81, the cube of it is 0.729



the square of 1. is 1., the cube of it is 1.

You can also use StandardForm, which is the standard format of output cells:

Do[Print[StringForm["the square of `` is ``, the cube of it is ``", 

   StandardForm[i], StandardForm[i^2], StandardForm[i^3]]],

 {i, 0.5, 6, 0.1}]